$ontext
Решается задача о работе мебельного комбината. Математическая модель записана
в терминах целочисленного линейного программирования.
$offtext

Sets
       i множество стульев / President, Secretary, Office, Captain, Marquise,
                         Viennese /
       j components  / short_bolt, long_bolt, straight_steam, bent_steam,
                         big_sedenion, standart_sedenion, wide_lath,
                         narrow_lath, big_arm, office_arm, bent_arm / ;
Parameters
        quantity(j) количество запасных частей на складе
         /   short_bolt        2560
             long_bolt         3200
             straight_steam    1500
             bent_steam         800
             big_sedenion       380
             standart_sedenion  340
             wide_lath         2000
             narrow_lath       2000
             big_arm            400
             office_arm         360
             bent_arm           400 /

        price(i) стоимость одного стула
        /    President 50
             Secretary 45
             Office 30
             Captain 40
             Marquise 45
             Viennese 30 /
;

Table c(j,i) количество компонент необходимых для производства одного стула
                   President  Secretary   Office   Captain   Marquise   Viennese
short_bolt            8          0         12         0         8          4
long_bolt             4         12          0        12         4          8
straight_steam        4          4          4         4         0          0
bent_steam            1          0          0         0         4          4
big_sedenion          0          0          0         1         1          0
standart_sedenion     6          1          1         0         0          1
wide_lath             0          0          0         4         5          0
narrow_lath           1          4          5         0         2          6
big_arm               0          0          0         2         0          0
office_arm            0          2          2         0         0          0
bent_arm              0          0          0         0         2          2
;


Free Variables
      z    суммарный доход от продажи стульев
;

Integer Variables
      x(i) количество производимых стульев i-го типа;
x.up(i)=999999;

Equations
profit    суммарный доход от продажи
limit_constraints(j)  ограничение на количество запасных частей на складе
;

profit..         z =e= sum(i,x(i)*price(i));
limit_constraints(j)..  sum(i,c(j,i)*x(i)) =l= quantity(j);

Model Chairs /profit, limit_constraints/;
*Model Chairs /all/;

Chairs.optcr=0.0;

Solve Chairs using mip max z ;

Display x.l, z.l, limit_constraints.l ;