#We find all primitive subgroups of $GL(4,19)$ with parameters $e=2$, $a=2$
#In the notations of Theorem 5.1, if $H$ is a primitive solvable subgroup, then it possesses a series

#$$1<U<F<A<H,$$

#where $U$ is cyclic of order $19^2-1$, $F=U\circ E$ and $E$ is extraspecial of order $2^{1+2}$, moreover
#in this case $|H:A|$ divides $2$. Since $b=2$ divides $a=2$, Lemma 5.3 implies that up to conjugation there is one $F$, and
#$N_{L}(F)/F\simeq Sp(2,2)\simeq S_3$, where $L=C_{GL(4,19)}(U)$.

gap> e:=2;; p:=19;; d:=4;; a:=2;;

#Now we generate the list of all primitive subgroups in $GL(4,19)$, using standart function of the package IRREDSOL

gap> l0:=AllIrreducibleSolvableMatrixGroups(Degree,d,Field,GF(p),IsPrimitiveMatrixGroup,true);;

#In this list we choose subgroups, whose order is divisible by the order of $F$ in the notations of Theorem 5.1

gap> l1:=Filtered(l0,x-> (Order(x) mod ((p^a-1)*e*e)) = 0);;

#In view of Lemma 5.3, we choose subgroups satisfying $\vert A/F\vert\in \{2,6\}$ and collect these subgroups in the list l2.

gap> l2:=Filtered(l1,x-> (Order(x)/((p^a-1)*e*e)) in  [2,6,2*2,6*2]);; Size(l2);
19

#Now we define a function which check, if the $2$-closure of a group $g$ aacting on $v^g$ is equal to $g$, so that Lemma 4.4 can be applied. This function uses
#COCO2P package

gap> twoc:=function(g,v)
>     local h,a;
>     h:=Action(g,v^g,OnRight);
>     a:=AutomorphismGroup(ColorGraph(h));
>     return IsSubgroup(a,h) and IsSubgroup(h,a);
> end;
function( g, v ) ... end

#We check that Lemma 4.4 is satisfied for all g in the list l2, i.e. that every subgroup g in the  list l2 is 2-closed on v^g.

gap> v:=[Z(19),Z(19),0*Z(19),Z(19)];;
gap> result:=[];; i:=0;;
gap> for j in l2 do
> tf:=twoc(j,v);; i:=i+1;; n:=Size(j);;                   
> Append(result,[[i,n,tf]]);;
> Display([i,n,tf]);
> od;
[ 1, 17280, true ]
[ 2, 8640, true ]
[ 3, 8640, true ]
[ 4, 8640, true ]
[ 5, 8640, true ]
[ 6, 8640, true ]
[ 7, 8640, true ]
[ 8, 5760, true ]
[ 9, 2880, true ]
[ 10, 2880, true ]
[ 11, 2880, true ]
[ 12, 2880, true ]
[ 13, 2880, true ]
[ 14, 2880, true ]
[ 15, 2880, true ]
[ 16, 5760, true ]
[ 17, 2880, true ]
[ 18, 8640, true ]
[ 19, 2880, true ]