#In Short's notation solvable subgroup G of GL(4,67) with parameters e=2, a=2
#In the notations of Theorem 5.1, if $H$ is a primitive solvable subgroup, then it possesses a series

#$$1<U<F<A<H,$$

#where $U$ is cyclic of order $67^2-1$, $F=U\circ E$ and $E$ is extraspecial of order $2^{1+2}$, moreover
#in this case $|H:A|$ divides $2$. Since $b=2$ divides $a=2$, Lemma 5.3 implies that there is up to conjugation there is one $F$, and
#$N_{L}(F)/F\simeq Sp(2,2)\simeq S_3$, where $L=C_{GL(4,67)}(U)$. Since $O^-(2,2)=Sp(2,2)$, we obtain primitive subgroups in $GL(2,67)$ first, and then
#produce primitive subgroups in $GL(4,67)$ by using Lemma 5.5(i)


#First we generate maximal primitive solvable subgroups of GL(2,67)


gap> e:=2;; p:=67;; d:=4;; a:=2;;

#First we generate maximal primitive solvable subgroups of GL(2,67)


gap> l0:=AllIrreducibleSolvableMatrixGroups(Degree, e, Field, GF(p), IsPrimitiveMatrixGroup, true);; 

#In this list we choose subgroups, whose order is divisible by $(p-1)*e*e$ in the notations of Theorem 5.1


gap> l1:=Filtered(l0,x-> (Order(x) mod ((p-1)*e*e)) = 0);;

#In view of Lemma 5.3, we choose subgroups satisfying $\vert A/F\vert\in \{6\}$ and collect these subgroups in the list l2.

gap> l2:=Filtered(l1,x-> ((Order(x)/((p-1)*e*e)) mod 6)=0);; Size(l2);
1
gap> gens:=GeneratorsOfGroup(l2[1]);;

#Now we need to make an embedding of the primitive solvable subgroups of $GL(e,p)=GL(2,67)$ into $GL(d,p)=GL(4,67)$. 
#According to Lemma 5.5 (i), for every primitive solvable subgroup
#G from the list l2 we take $I_2\otimes G$.

gap> I2:=IdentityMat(2,GF(p));;
gap> genS:=[];;
gap> for k in [1..Size(gens)] do
> genS[k]:=KroneckerProduct(I2,gens[k]);
> od;

#Now we add $t\otimes I_e$, $s\otimes I_e$ to the list of generators, where t is a Singer cycle of $GL(a,p)$, and $t^s=t^p$.

gap> bas:= Basis(AsVectorSpace( GF(p),GF(p^a) ) );;
gap> t:=BlownUpMat(bas,[[Z(p^a)]]);;
gap> s:=RepresentativeAction(GL(a,p),t,t^p);;
gap> Ie:=IdentityMat(e,GF(p));;
gap> td:=KroneckerProduct(t,Ie);;
gap> sd:=KroneckerProduct(s,Ie);;

#Now we make generators of H


gap> Append(genS,[td,sd]);;

#Now we take vector v, generate H and check that $|H|=|v^H|$, so that Corollary 2.5 can be applied


gap> z:=Z(67);; v:=[z,0*z,0*z,z];;
gap> H:=Subgroup(GL(4,67),genS);;
gap> n:=Size(H);; m:=Size(v^H);; n/m;
1