#We find all primitive subgroups of $GL(6,17)$ with parameters $e=2$, $a=3$
#In the notations of Theorem 5.1, if $H$ is a primitive solvable subgroup, then it possesses a series

#$$1<U<F<A<H,$$

#where $U$ is cyclic of order $17^3-1$, $F=U\circ E$ and $E$ is extraspecial of order $2^{1+2}$, moreover
#in this case $|H:A|$ divides $2$. Since $b=1$ divides $a=3$, Lemma 5.3 implies that there is up to conjugation there is one $F$, and
#$N_{L}(F)/F\simeq Sp(2,2)\simeq S_3$, where $L=C_{GL(6,17)}(U)$. We use Lemma 5.5(i) to obtain primitive solvable subgroups in $GL(6,17)$.

gap> e:=2;; p:=17;; d:=6;; a:=3;; b:=1;;

#By Lemma 5.5(i) first we generate the list of all primitive subgroups in $GL(2,17)$, using standart function of the package IRREDSOL

gap> l0:=AllIrreducibleSolvableMatrixGroups(Degree,e,Field,GF(p^b),IsPrimitiveMatrixGroup,true);;

#In this list we choose subgroups, whose order is divisible by $(p^b-1)*e*e$ in the notations of Theorem 5.1

gap> l1:=Filtered(l0,x-> (Order(x) mod ((p^b-1)*e*e)) = 0);;

#In view of Lemma 6.3, we choose subgroups satisfying $\vert A/F\vert\in \{6\}$ and collect these subgroups in the list l2.

gap> l2:=Filtered(l1,x-> (Order(x)/((p^b-1)*e*e)) in  [6]);; Size(l2);
1
gap> gens:=GeneratorsOfGroup(l2[1]);;

#Now we need to make an embedding of the primitive solvable subgroups of $GL(e,p)=GL(2,17)$ into $GL(d,p)=GL(6,17)$. 
#According to Lemma 5.5 (i), for every primitive solvable subgroup
#G from the list l2 we take $I_a\otimes G$.

gap> Ia:=IdentityMat(a,GF(p));;
gap> genS:=[];;
gap> for k in [1..Size(gens)] do
> genS[k]:=KroneckerProduct(Ia,gens[k]);
> od;

#Now we add $t\otimes I_e$, $s\otimes I_e$ to the list of generators, where t is a Singer cycle of $GL(a,p)$, and $t^s=t^p$.

gap> bas:= Basis(AsVectorSpace( GF(p),GF(p^a) ) );;
gap> t:=BlownUpMat(bas,[[Z(p^a)]]);;
gap> s:=RepresentativeAction(GL(a,p),t,t^p);;
gap> Ie:=IdentityMat(e,GF(p));;
gap> td:=KroneckerProduct(t,Ie);;
gap> sd:=KroneckerProduct(s,Ie);;

#Now we make generators of H


gap> Append(genS,[td,sd]);;


#Now we take vector v, generate H and check that $|H|=|v^H|$, so that Corollary 2.5 can be applied

gap> z:=Z(17);; v:=[z,z^2,z^7,z^11,z^13,0*z];;
gap> H:=Subgroup(GL(6,17),genS);;
gap> n:=Size(H);; m:=Size(v^H);; n/m;
1