#We find all primitive subgroups of $GL(9,7)$ with parameters $e=3$, $a=3$
#In the notations of Theorem 5.1, if $H$ is a primitive solvable subgroup, then it possesses a series

#$$1<U<F<A<H,$$

#where $U$ is cyclic of order $7^3-1$, $F=U\circ E$ and $E$ is extraspecial of order $3^{1+2}$, moreover
#in this case $|H:A|$ divides $3$.

gap> e:=3;; p:=7;; d:=9;; a:=3;; b:=1;;

#Since $b=1$ divides $a=3$, we use Lemma 5.5(i) to obtain the list of primitive solvable subgroups in $GL(e,p^b)=GL(3,7)$ with parameters $e=3,a=1$ by using 
#standart function of the package IRREDSOL


gap> l0:=AllIrreducibleSolvableMatrixGroups(Degree, e, Field, GF(p^b), IsPrimitiveMatrixGroup, true);;

#In this list we choose subgroups, whose order is divisible by $(p^b-1)*e*e$. 

#We choose subgroups of order divisible by $(p^b-1)*e*e=6*9$

gap> l1:=Filtered(l0,x-> (Order(x) mod ((p^b-1)*e*e)) = 0);; 

#In view of Lemma 5.4, we choose subgroups satisfying $\vert A/F\vert\in \{24\}$ and collect these subgroups in the list l2.
 
gap> l2:=Filtered(l1,x-> (Order(x)/((p^b-1)*e*e)) in  [24]);;   Size(l2);
1


#Now we need to make an embedding of the primitive solvable subgroups of $GL(e,p^b)=GL(3,7)$ into $GL(d,p)=GL(9,7)$. 
#According to Lemma 5.5 (i), for every primitive solvable subgroup
#G from the list l2 we take $I_a\otimes G$.

gap> gens:=[];;
gap> for j in l2 do                      
> Append(gens,[GeneratorsOfGroup(j)]);;
> od;
gap> genS:=[];;
gap> for i in [1..Size(gens)] do
> genS[i]:=[];
> for j in gens[i] do
> Append(genS[i],[KroneckerProduct(IdentityMat(a,Z(p)),j)]);
> od;
> od;

#Now we add $t\otimes I_e$, $s\otimes I_e$ to the list of generators, where t is a Singer cycle of $GL(a,p)$, and $t^s=t^p$.

gap> bas:= Basis(AsVectorSpace( GF(p),GF(p^a) ) );;
gap> t:=BlownUpMat(bas,[[Z(p^a)]]);;
gap> s:=RepresentativeAction(GL(a,p),t,t^p);;
gap> Ie:=IdentityMat(e,GF(p));;
gap> td:=KroneckerProduct(t,Ie);;
gap> sd:=KroneckerProduct(s,Ie);;

#Now we add generators td and sd to the generators of subgroups in the list

gap> for k in genS do
gap> Append(k,[td,sd]);;
gap> od;





#Finally we produce vector v, take the subgroup H generated by genS[1], and check, that |v^H|=|H|, so that Corollary 2.5 can be applied

gap> z:=Z(7);; v:=[z,z^2,z^3,z^4,z^5,0*z,z,z^5,z^2];;
gap> H:=Subgroup(GL(9,7),genS[1]);; n:=Size(H);;
gap> m:=Size(v^H);; n/m;
1