#We find all primitive subgroups of $GL(20,3)$ with parameters $e=4$, $a=5$. Since $b=2$ does not divide $a=5$ we use Lemma 5.5(ii) to obtain primitive solvable 
#subgroups in $GL(d,p)=GL(20,3)$ by using primitive subgroups in $GL(e,p)=GL(4,3)$.
#In the notations of Theorem 5.1, if $H$ is a primitive solvable subgroup, then it possesses a series

#$$1<U<F<A<H,$$

#where $U$ is cyclic of order $p^a-1=242$, $F=U\circ E$ and $E$ is extraspecial of order $2^{1+4}$. Since $b$ does not divides $a$, Lemma 5.3 implies
#that $GL(d,p)$ has two  nonconjugate subgroups $F_1$ and $F_2$  with this structture such that $N_L(F_1)/F_1\simeq O^+(4,2)$, while 
#$N_L(F_2)/F2\simeq O^-(4,2)$, where $L=C_{GL(d,p)}(U)$. In this case $|H:A|$ divides 5 (in view of Lemma 5.5(ii), $|H:A|=5$). 

#First we make general variables:

gap> e:=4;; p:=3;; d:=20;; a:=5;; b:=2;;

#Since $b=2$ does not divide $a=1$, we use Lemma 5.5(ii) to obtain the list of primitive solvable subgroups in $GL(e,p)=GL(4,3)$ with parameters $e=4,a=1$ by using 
#standart function of the package IRREDSOL


gap> l0:=AllIrreducibleSolvableMatrixGroups(Degree, e, Field, GF(p), IsPrimitiveMatrixGroup, true);;

#In this list we choose subgroups, whose order is divisible by $(p-1)*e*e$. 

gap> l1:=Filtered(l0,x-> (Order(x) mod ((p-1)*e*e)) = 0);; 

#In view of Lemma 5.4, we choose subgroups satisfying $\vert A/F\vert\in \{12,20,72\}$ and collect these subgroups in the list l2.
 
gap> l2:=Filtered(l1,x-> (Order(x)/((p-1)*e*e)) in  [12, 20,72]);;   Size(l2);
2


#Now we need to make an embedding of the primitive solvable subgroups of $GL(e,p)=GL(4,3)$ into $GL(d,p)=GL(20,3)$. 
#According to Lemma 5.5 (ii), for every primitive solvable subgroup
#G from the list l2 we take $I_2\otimes G$.

gap> gens:=[];;
gap> for j in l2 do                      
> Append(gens,[GeneratorsOfGroup(j)]);;
> od;
gap> genS:=[];;
gap> for i in [1..Size(gens)] do
> genS[i]:=[];
> for j in gens[i] do
> Append(genS[i],[KroneckerProduct(IdentityMat(a,Z(p)),j)]);
> od;
> od;

#Now we add $t\otimes I_e$, $s\otimes I_e$ to the list of generators, where t is a Singer cycle of $GL(a,p)$, and $t^s=t^p$.

gap> bas:= Basis(AsVectorSpace( GF(p),GF(p^a) ) );;
gap> t:=BlownUpMat(bas,[[Z(p^a)]]);;
gap> s:=RepresentativeAction(GL(a,p),t,t^p);;
gap> Ie:=IdentityMat(e,GF(p));;
gap> td:=KroneckerProduct(t,Ie);;
gap> sd:=KroneckerProduct(s,Ie);;

#Now we add generators td and sd to the generators of subgroups in the list

gap> for k in genS do
gap> Append(k,[td,sd]);;
gap> od;

#Now we run the following loop. Each entry of the list result has three items: the first is the
#number of the group in the list genS, the second is the order of the group, and the third is the order of the stabilizer of v in H. 
#If the order of the stabilizer is 1, then |v^H=|H| and Corollary 2.5 can be applied.

gap> z:=Z(p);; v:=[z,z^2,0*z,z^2,z,z^2,z,0*z,z,z,z^2,z^2,z,0*z,z,z^2,z^2,z^2,z,z];;
gap> result:=[];; i:=0;;
gap> for k in genS do
> H:=Subgroup(GL(d,p),k);; i:=i+1;;
> n:=Size(H);; m:=Size(v^H);;
> result[i]:=[i,n,n/m];
> Display(result[i]);
> od;
[ 1, 1393920, 1 ]
[ 2, 232320, 1 ]
[ 3, 387200, 1 ]