#We find all primitive subgroups of $GL(4,3)$ with parameters $e=4$, $a=1$. 
#In the notations of Theorem 5.1, if $H\leq GL(4,3)$ is a primitive solvable subgroup, then it possesses a series

#$$1<U<F<A<H,$$

#where $U$ is cyclic of order $2$, $F=U\circ E$ and $E$ is extraspecial of order $2^{1+4}$, moreover
#in this case $|H:A|$ equals $1$. Since $b=2$ does not divide $a=1$, Lemma 5.3 implies that there are two nonconjugate subgroups $F_1$ and $F_2$, and
#$N_{GL(4,3)}(F_1)/F_1\simeq Q^+(4,2)$, while  $N_{GL(4,3)}(F_2)/F_2\simeq Q^-(4,2)$


#First we generate the list of all primitive subgroups in $GL(4,3)$, using standart function of the package IRREDSOL

gap> e:=4;; p:=3;; d:=4;; a:=1;; b:=2;;

#Now we generate the list of all primitive subgroups in $GL(4,3)$, using standart function of the package IRREDSOL

gap> l0:=AllIrreducibleSolvableMatrixGroups(Degree,d/a,Field,GF(p),IsPrimitiveMatrixGroup,true);;

#In this list we choose subgroups, whose order is divisible by the order of $F$ in the notations of Theorem 5.1

gap> l1:=Filtered(l0,x-> (Order(x) mod ((p-1)*e*e)) = 0);;

#In view of Lemma 5.4, we choose subgroups satisfying $\vert A/F\vert\in  \{12,20,72\}$ and collect these subgroups in the list l2.

gap> l2:=Filtered(l1,x-> (Order(x)/((p-1)*e*e)) in  [12,20,72]);;

#Now we define a function which check, if the $2$-closure of a group $g$ aacting on $v^g$ is equal to $g$, so that Lemma 4.4 can be applied. This function uses
#COCO2P package

gap> twoc:=function(g,v)
>     local h,a;
>     h:=Action(g,v^g,OnRight);
>     a:=AutomorphismGroup(ColorGraph(h));
>     return IsSubgroup(a,h) and IsSubgroup(h,a);
> end;
function( g, v ) ... end

#We check that Lemma 4.4 is satisfied for all g in the list l2, i.e. that every subgroup g in the  list l2 is 2-closed on v^g.
 
gap> v:=[Z(3),Z(3),0*Z(3),Z(3)];;
gap> result:=[];; 
gap> for j in l2 do
> tf:=twoc(j,v);;
> n:=Size(j);;                   
> Append(result,[[n,tf]]);;
> Display([n,tf]);
> od;
[ 2304, true ]
[ 384, true ]
[ 640, true ]