#We find all primitive subgroups of $GL(8,7)$ with parameters $e=4$, $a=2$. In this case $b=2$ divides $a=2$.
#In the notations of Theorem 5.1, if $H$ is a primitive solvable subgroup, then it possesses a series

#$$1<U<F<A<H,$$

#where $U$ is cyclic of order $p^a-1=11^2-1=120$, $F=U\circ E$, $F/U$ is elementary abelian of order $e^2=4^2=2^4$ and $E$ is extraspecial of order $2^{1+4}$, 
#moreover in this case $|H:A|$ divides $2$ and $A/F$ is a subgroup with trivial $2$-radical of $Sp(4,2)$. By Lemma 5.4 we obtain that either $A/F=O^+(4,2)$ of 
#order 72, or $A/F=5:4\leq O^-(4,2)$ of order 20. We also know that $GL(4,11)$ contains two nonconjugate subgroups $F_1$ and $F_2$ 
#such that both of them have  normal cyclic subgroup $U_1$ of order $p-1=10$ and $|F_i/U_1|=e^2=16$ for $i=1,2$; and
#$N_{GL(4,11)}(F_1)/F_1\simeq Q^+(4,2)$, while  $N_{GL(4,11)}(F_2)/F_2\simeq Q^-(4,2)$.  So we can start with primitive solvable subgroups in $GL(4,11)$ of orders
#$(p-1)*e^2*20=10*16*20$ and $(p-1)*e^2*72=10*16*72$ and then obtain primitive subgroups in $GL(8,11)$ by using tensor products from Lemma 5.5(ii).

gap> e:=4;; p:=11;; d:=8;; a:=2;; b:=2;;

#Now we generate the list of all primitive subgroups in $GL(e,p)=GL(4,11)$, using standart function of the package IRREDSOL

gap> l0:=AllIrreducibleSolvableMatrixGroups(Degree, d/2, Field, GF(p), IsPrimitiveMatrixGroup, true);;

#In this list we choose subgroups, whose order is divisible by the order of $F$ in the notations of Theorem 5.1

gap> l1:=Filtered(l0,x-> (Order(x) mod ((p-1)*e*e)) = 0);;  

#In view of Lemma 5.4, we choose subgroups satisfying $\vert A/F\vert\in \{20,72\}$ and collect these subgroups in the list l2.

gap> l2:=Filtered(l1,x-> (Order(x)/((p-1)*e*e)) in  [20,72]);; Size(l2);
2

#Now we need to make an embedding of the primitive solvable subgroups of $GL(e,p)=GL(4,11)$ into $GL(d,p)=GL(8,11)$. 
#First each $G\leq GL(4,11)$ we embed in $GL(8,11)$ by taking $I_2\otimes G$
#First we produce generators of subgroups from the list l2 


gap> gens:=[];;
gap> for k in l2 do
> Append(gens,[GeneratorsOfGroup(k)]);;
> od;

#Each matrix $g$ in gens we substitute by $I_2\otimes g$.

gap> genS:=[];;
gap> for i in [1..Size(gens)] do
> genS[i]:=[];
> for j in gens[i] do
> Append(genS[i],[KroneckerProduct(IdentityMat(2,Z(11)),j)]);
> od;
> od;

#Now we add $t\otimes I_e$, $s\otimes I_e$ to the list of generators, where t is a Singer cycle of $GL(d/e,p)$, and $t^s=t^p$.

gap> bas:= Basis(AsVectorSpace( GF(p),GF(p^2) ) );;
gap> t:=BlownUpMat(bas,[[Z(p^a)]]);;
gap> s:=RepresentativeAction(GL(a,p),t,t^p);;
gap> Ie:=IdentityMat(e,GF(p));; td:=KroneckerProduct(t,Ie);; sd:=KroneckerProduct(s,Ie);;

#Now we add generators td and sd to the generators of subgroups in the list

gap> for k in genS do
gap> Append(k,[td,sd]);;
gap> od;

#Now we run the following loop. Each entry of the list result has three items: the first is the
#number of the group in the list genS, the second is the order of the group, and the third is the order of the stabilizer of v in H. 
#If the order of the stabilizer is 1, then |v^H=|H| and Corollary 2.5 can be applied.

gap> z:=Z(p);; v:=[z,z^3,z^7,z^9,0*z,z^2,z^4,z^5];;
gap> result:=[];; i:=0;;
gap> for k in genS do
> H:=Subgroup(GL(8,11),k);; i:=i+1;;
> n:=Size(H);; m:=Size(v^H);;
> result[i]:=[i,n,n/m];
> Display(result[i]);
> od;
[ 1, 276480, 1 ]
[ 2, 76800, 1 ]