#We find all primitive subgroups of $GL(16,5)$ with parameters $e=8$, $a=2$
#In the notations of Theorem 5.1, if $H$ is a primitive solvable subgroup, then it possesses a series

#$$1<U<F<A<H,$$

#where $U$ is cyclic of order $p^2-1=24$, $F=U\circ E$ and $E$ is extraspecial of order $2^{1+4}$, in this case $|H:A|$ divides 2 
#(in view of Lemma 5.5(i), $|H:A|=2$). 

#First we make general variables:

gap> e:=4;; p:=13;; d:=8;; a:=2;; b:=1;;

#Since $b=1$ divides $a=2$, we use Lemma 5.5(i) to obtain the list of primitive solvable subgroups in $GL(e,p^b)=GL(4,13)$ with parameters $e=4,a=1$ by using 
#standart function of the package IRREDSOL


gap> l0:=AllIrreducibleSolvableMatrixGroups(Degree, e, Field, GF(p^b), IsPrimitiveMatrixGroup, true);;

#In this list we choose subgroups, whose order is divisible by $(p^b-1)*e*e$. 


gap> l1:=Filtered(l0,x-> (Order(x) mod ((p^b-1)*e*e)) = 0);; 

#In view of Lemma 5.4, we choose subgroups satisfying $\vert A/F\vert\in \{20,72\}$ and collect these subgroups in the list l2.
 
gap> l2:=Filtered(l1,x-> (Order(x)/((p^b-1)*e*e)) in  [20,72]);;   Size(l2);
2


#Now we need to make an embedding of the primitive solvable subgroups of $GL(e,p^b)=GL(4,13)$ into $GL(d,p)=GL(8,13)$. 
#According to Lemma 5.5 (i), for every primitive solvable subgroup
#G from the list l2 we take $I_2\otimes G$.

gap> gens:=[];;
gap> for j in l2 do                      
> Append(gens,[GeneratorsOfGroup(j)]);;
> od;
gap> genS:=[];;
gap> for i in [1..Size(gens)] do
> genS[i]:=[];
> for j in gens[i] do
> Append(genS[i],[KroneckerProduct(IdentityMat(2,Z(p)),j)]);
> od;
> od;

#Now we add $t\otimes I_e$, $s\otimes I_e$ to the list of generators, where t is a Singer cycle of $GL(a,p)$, and $t^s=t^p$.

gap> bas:= Basis(AsVectorSpace( GF(p),GF(p^a) ) );;
gap> t:=BlownUpMat(bas,[[Z(p^a)]]);;
gap> s:=RepresentativeAction(GL(a,p),t,t^p);;
gap> Ie:=IdentityMat(e,GF(p));;
gap> td:=KroneckerProduct(t,Ie);;
gap> sd:=KroneckerProduct(s,Ie);;

#Now we add generators td and sd to the generators of subgroups in the list

gap> for k in genS do
gap> Append(k,[td,sd]);;
gap> od;

#Now we run the following loop. Each entry of the list result has three items: the first is the
#number of the group in the list genS, the second is the order of the group, and the third is the order of the stabilizer of v in H. 
#If the order of the stabilizer is 1, then |v^H=|H| and Corollary 2.5 can be applied.

gap> z:=Z(p);; v:=[z,z^3,z^4,z^5,z^7,z^11,z^8,0*z];;
gap> result:=[];; i:=0;;
gap> for k in genS do
> H:=Subgroup(GL(d,p),k);; i:=i+1;;
> n:=Size(H);; m:=Size(v^H);;
> result[i]:=[i,n,n/m];
> Display(result[i]);
> od;
[ 1, 387072, 1 ]
[ 2, 107520, 1 ]