#We find all primitive subgroups of $GL(16,5)$ with parameters $e=8$, $a=2$
#In the notations of Theorem 5.1, if $H$ is a primitive solvable subgroup, then it possesses a series

#$$1<U<F<A<H,$$

#where $U$ is cyclic of order $24$, $F=U\circ E$ and $E$ is extraspecial of order $2^{1+6}$, in this case $|H:A|$ divides 2 (in view of Lemma 5.5(i), $|H:A|=2$). 

#First we make general variables:

gap> e:=8;; p:=5;; d:=16;; a:=2;; b:=1;;

#Since $b=1$ divides $a=2$, we use Lemma 5.5(i) to obtain the list of primitive solvable subgroups in GL(16,5) with parameters $e=8,a=2$. 
#Now we generate the list of all primitive subgroups in $GL(8,5)$, using standart function of the package IRREDSOL

gap> l0:=AllIrreducibleSolvableMatrixGroups(Degree,d/a,Field,GF(p),IsPrimitiveMatrixGroup,true);;

#In this list we choose subgroups, whose order is divisible by the order of $F$ in the notations of Theorem 5.1

gap> l1:=Filtered(l0,x-> (Order(x) mod ((p^b-1)*e*e)) = 0);;

#In view of Lemma 5.4, we choose subgroups satisfying $\vert A/F\vert\in \{120, 42, 1296\}$ and collect these subgroups in the list l2.

gap> l2:=Filtered(l1,x-> (Order(x)/((p^b-1)*e*e)) in  [120, 42, 1296]);;
gap> Size(l2);
4



#Now we need to make an embedding of the primitive solvable subgroups of GL(8,5) into GL(16,5). According to Lemma 5.5 (i), for every primitive solvable subgroup
#G from the list l2 we take $I_2\otimes G$.

gap> gens:=[];;
gap> for j in l2 do                      
> Append(gens,[GeneratorsOfGroup(j)]);;
> od;
gap> genS:=[];;
gap> for i in [1..Size(gens)] do
> genS[i]:=[];
> for j in gens[i] do
> Append(genS[i],[KroneckerProduct(IdentityMat(2,Z(5)),j)]);
> od;
> od;

#Now we add $t\otimes I_8$, $s\otimes I_8$ to the list of generators, where t is a Singer cycle of $GL(2,5)$, and $t^s=t^5$.

gap> bas:= Basis(AsVectorSpace( GF(p),GF(p^a) ) );;
gap> t:=BlownUpMat(bas,[[Z(p^a)]]);;
gap> s:=RepresentativeAction(GL(a,p),t,t^p);;
gap> I8:=IdentityMat(e,GF(p));;
gap> t16:=KroneckerProduct(t,I8);;
gap> s16:=KroneckerProduct(s,I8);;

#Now we add generators t16 and s16 to the generators of subgroups in the list

gap> for k in genS do
gap> Append(k,[t16,s16]);;
gap> od;

#Now we run the following loop. Each entry of the list result has three items: the first is the
#number of the group in the list genS, the second is the order of the group, and the third is the order of the stabilizer of v in H. 
#If the order of the stabilizer is 1, then |v^H=|H| and Corollary 2.5 can be applied.

gap> z:=Z(5);;
gap> v:=[z,z^2,z^3,0*z,z^2,z^3,z,z^3,0*z,z,z^2,z,z^3,z^2,z,z^3];;
gap> result:=[];;
gap> for j in [1..Size(genS)] do
> H:=Subgroup(GL(d,p),genS[j]);;
> n:=Size(H);;
> m:=Size(v^H);
> result[j]:=[j,n,n/m];
> Display(result[j]);
> od;
[ 1, 368640, 1 ]
[ 2, 3981312, 1 ]
[ 3, 129024, 1 ]
[ 4, 3981312, 1 ]