#We find all primitive subgroups of $GL(8,5)$ with parameters $e=8$, $a=1$
#In the notations of Theorem 5.1, if $H$ is a primitive solvable subgroup, then it possesses a series

#$$1<U<F<A<H,$$

#where $U$ is cyclic of order $4$, $F=U\circ E$ and $E$ is extraspecial of order $2^{1+6}$, in this case $H=A$. 

#First we make general variables:

gap> e:=8;; p:=5;; d:=8;; a:=1;;

#Now we generate the list of all primitive subgroups in $GL(8,5)$, using standart function of the package IRREDSOL

gap> l0:=AllIrreducibleSolvableMatrixGroups(Degree,d,Field,GF(p),IsPrimitiveMatrixGroup,true);;

#In this list we choose subgroups, whose order is divisible by the order of $F$ in the notations of Theorem 5.1

gap> l1:=Filtered(l0,x-> (Order(x) mod ((p^a-1)*e*e)) = 0);;

#In view of Lemma 5.4, we choose subgroups satisfying $\vert A/F\vert\in \{120, 42, 1296\}$ and collect these subgroups in the list l2.

gap> l2:=Filtered(l1,x-> (Order(x)/((p^a-1)*e*e)) in  [120, 42, 1296]);;

#Now we define a function which check, if the $2$-closure of a group $g$ aacting on $v^g$ is equal to $g$, so that Lemma 4.4 can be applied. This function uses
#COCO2P package

gap> twoc:=function(g,v)
>     local h,a;
>     h:=Action(g,v^g,OnRight);
>     a:=AutomorphismGroup(ColorGraph(h));
>     return IsSubgroup(a,h) and IsSubgroup(h,a);
> end;
function( g, v ) ... end
gap>

#We check that Lemma 4.4 is satisfied for all g in the list l2, i.e. that every subgroup g in the  list l2 is 2-closed on v^g.


gap> v:=[Z(5),0*Z(5),0*Z(5),Z(5)^5,0*Z(5),Z(5),Z(5),0*Z(5)];;
gap> result:=[];; 
gap> for j in l2 do
> tf:=twoc(j,v);;
> n:=Size(j);;                   
> Append(result,[[n,tf]]);;
> Display([n,tf]);
> od;
[ 30720, true ]
[ 331776, true ]
[ 10752, true ]
[ 331776, true ]